La consultazione del forum è libera per tutti.
Per poter porre un quesito è invece necessario essere un utente registrato (clicca qui se non lo sei).
Tutti gli utenti che richiedono un supporto, come da REGOLAMENTO, sono caldamente invitati ad allegare un file di esempio con l'indicazione di quello che si desidera ottenere.
Ciao a tutti,
devo fare un elenco che finora ho compilato a mano, ma se fosse possibile inserire delle formule sarebbe molto meno dispendioso in termini di tempo e più comodo. Grazie.
Sto programmando un'attività di volontariato che si svolge per una durata prestabilita: 10 giorni. I partecipanti non sono presenti tutta la durata. Ho la necessità di avere un "foglio presenze" (da appendere al muro) con la presenza dei partecipanti ogni giorno (posso inserire un "X" o il nome o anche altro, è lo stesso).
I partecipanti comunicano la propria partecipazione e poi devo riportarla su un foglio presenze. E' possibile con una formula?
Grazie.
Alessandro
ciao
se i nomi sono in ordine
=SE(E($I5<>"";K$3=MEDIANA(K$3;$D5;$E5));"X";"")
altrimenti
in K5 la tiri a destra e in basso
=SE(E($I5<>"";K$3=MEDIANA(K$3;FILTRO($D$5:$E$25;($B$5:$B$25=$I5)*($C$5:$C$25=$J5))));"X";"")
ti ho diviso le date
creato la sequenza dei giorni con SEQUENZA()
e filtrato i nomi
ora basta la prima formula perchè i nomi corrispondono
Grazie mille!!!
Grazie !!!
Colui che l'anno scorso l'ha compilato a mano...ringrazia, soprattutto perchè se i componenti variano, e può accadare nei prossimi giorni, deve rifare tutto, mentre cosi non c'è problema.
Grazie.
Non riesco a inserire la formula nel campo delle date (riga da K3 aT3) perchè esce l'errore #ESPANSIONE! e non riesco a capire il perchè. Comunque ho risolto togliendo la formula e compilando a mano le date che al momento sono 8, quindi non è cosi complicato.
Grazie.
Alessandro
Ciao,
se possibile un'ultima info: ho inserito la formattazione condizionale per colorare le celle contenenti la X di grigio. ho dovuto inserire una regola per ogni colonna: dieci regole diverse con dieci intervalli diversi. E' possibile inserire una regola unica di formattazione condizionale per l'intero intervallo. Esempio: se alcune celle dell'intervallo A1:U100 contengono X (la cella A1 e la cella U90) queste si colorano di grigio, o funziona solo per colonne?
Grazie.
ciao
Non riesco a inserire la formula nel campo delle date (riga da K3 aT3) perchè esce l'errore #ESPANSIONE! e non riesco a capire il perchè
devi avere tutte le celle libere perciò devi cancellare le date da K3 a T3 minimo
e inserire la formula in K3.........ecco che si espande
per la formattazione....usiamo il file sopra
seleziona da K5 A T24
formattazione condizionale
formula
=k5="X"
in si applica a vedrai
=$K$5:$T$24
nel tuo esempio sarà
=A1="X"
si applica a
$A$1:$U$100
sta tutto negli assoluti che metti nella formula
$A1 blocchi la colonna
A$1 blocchi la riga
$A$1 blocchi tutto
A1 lasci che scorra nelle righe/colonne del si applica
ciao,
altra soluzione, in K5 e trascini a dx ed in basso
=SE(($D5<=K$3)*($E5>=K$3);"X";"")
Con excel 365, formula matriciale (si espande da sola)
=SE(($D5:$D13<=K$3:T$3)*($E5:$E13>=K$3:T$3);"X";"")
Ciao,
si ho excel 365 per mac. Dopo la provo. Ora ho sistemato con il suggerimento di Gianfranco perchè devo inviarlo agli altri e poi proseguire con altre incombenze di volontariato. Che dire........... gentilissimi e disponibili !!!! Grazie !!!! Veramente grazie.
Stavo pensando di utilizzarla anche per altra attività similare dove finora ho gestito manualmente. Una domanda, ma non è importante, se al posto della "X" volessi inserire il nome? quello riportato in J5? Cioè da K5 a T5 al posto della "X" viene indicato "MARIO". Ripeto non è importante anzi, non voglio usufruire troppo del vostro tempo, ma un altro utilizzo che mi è venuto in mente è questo: se potessi fare un elenco per ogni attività con indicato il nome.
Grazie mille.
Alessandro
ciao
certo
=SE(E($I5<>"";K$3=MEDIANA(K$3;$D5;$E5));$J5;"")
ma la formattazione diventa
=E(K5=$J5;$J5<>"")
matriciale
=SE(($D5:$D13<=K$3:T$3)*($E5:$E13>=K$3:T$3);$J5:$J13;"")
Non matriciale
=SE(($D5<=K$3)*($E5>=K$3);$J5;"")
Funziona tutto !!!!
Grazie mille !!!
Grazie.
ciao
benissimo
per favore chiudi la discussione
grazie
