Come ottenere tutte le proprietà di una cartella di lavoro

Quando si crea una cartella di lavoro, Excel tiene traccia di un bel po’ di informazioni a cui fa riferimento collettivamente come “proprietà” della cartella di lavoro. È possibile visualizzare le diverse proprietà gestite visualizzando la finestra di dialogo Proprietà.

In Word hai la possibilità di stampare le proprietà del documento, se lo desideri. Non esiste un modo intrinseco per stampare le proprietà della cartella di lavoro in Excel. È invece necessario ricorrere a una macro che inserirà i nomi e i valori delle proprietà in un foglio di lavoro. È quindi possibile stampare il foglio di lavoro e rendere disponibili le proprietà della cartella di lavoro in formato cartaceo.

La seguente macro è un esempio di un buon modo per copiare tutte le proprietà della cartella di lavoro in un foglio di lavoro che può essere stampato:

 

Public Sub WorkbookProperties()
    Dim p As DocumentProperty
    Dim iRow As Integer
    Dim WS As Worksheet
    'Aggiunge un nuovo foglio di lavoro per le info
    Set WS = Worksheets.Add
    'Proprietà integrate
    iRow = 1
    WS.Cells(iRow, 1).Value = "Proprietà integrate"
    WS.Cells(iRow, 1).Font.Bold = True
    iRow = iRow + 1
    WS.Activate
    For Each p In ActiveWorkbook.BuiltinDocumentProperties
        On Error Resume Next
        WS.Cells(iRow, 2).Value = p.Name
        'Se nessun valore, Excel causa un errore, quindi ignoralo!
        WS.Cells(iRow, 3).Value = p.Value
        iRow = iRow + 1
    Next
    On Error GoTo 0
    'Proprietà personalizzate
    iRow = iRow + 1
    WS.Cells(iRow, 1).Value = "Proprietà personalizzate"
    WS.Cells(iRow, 1).Font.Bold = True
    iRow = iRow + 1
    For Each p In ActiveWorkbook.CustomDocumentProperties
        On Error Resume Next
        WS.Cells(iRow, 2).Value = p.Name
        WS.Cells(iRow, 3).Value = p.Value
        iRow = iRow + 1
    Next
    On Error GoTo 0
    
    Set WS = Nothing
    
End Sub

 

 

 

Tags: , , , , , , , , , , , , ,

Ti è stato utile?