Come esportare grafici in bianco e nero

Excel ti consente di creare grafici a colori. Quando sei pronto per stampare il grafico, puoi indicare a Excel di stamparlo in “bianco e nero” (nella scheda Grafico della finestra di dialogo Imposta pagina). Potresti chiederti se esista un modo per esportare questa versione “in bianco e nero” del grafico, in modo da poterla lavorare in un programma diverso.

La risposta è che non è possibile farlo, almeno non direttamente. Per capire il motivo, è necessario capire come funziona la funzione “stampa in bianco e nero”. Questa funzionalità influisce solo su ciò che viene inviato al driver della stampante (alla tua stampante), non influisce affatto sul grafico vero e proprio. Anche quando utilizzi Anteprima di stampa, non stai visualizzando il tuo grafico reale, ma una rappresentazione di come apparirà il tuo grafico una volta stampato. Pertanto, viene visualizzato l’output della stampante, non il grafico reale.

Se desideri esportare una versione in bianco e nero del tuo grafico, esistono diversi modi per eseguire l’operazione. Il primo è semplicemente visualizzare il grafico in Anteprima di stampa ed acquisire una schermata (premendo Alt+Stamp). Puoi quindi incollare la schermata nel tuo programma di grafica preferito e ritoccarlo, come desideri.

Se desideri esportare il grafico invece di catturare semplicemente lo schermo, dovresti modificare i colori del grafico in modo che siano realmente in scala di grigi e contengano gli stessi motivi che vedresti se scegliessi di stampare in bianco e nero. Questo approccio modifica effettivamente l’origine del grafico, anziché fare affidamento su Excel per eseguire una trasformazione del grafico durante la stampa. Una volta apportate le modifiche alla formattazione, puoi anche salvare il grafico come “modello di grafico” in modo da poterlo utilizzare come modello per altri grafici che crei.

Se lo desideri, è anche possibile utilizzare una macro per passare tra la presentazione del grafico a colori e quella in scala di grigi. Questo approccio dipende fortemente dai colori che desideri utilizzare nel grafico, dal tipo di grafico che stai utilizzando e dal numero di serie di dati nel grafico. Di seguito è riportato un esempio di una macro capace di alternare i colori in una serie di dati tra colore e bianco e nero, per un massimo di cinque serie di dati.

 

Option Explicit
Public bColored As Integer
Sub ColoredToBW()
    Dim cht As Chart
    Dim chtSC As SeriesCollection
    Dim x As Integer
    Dim iSeriesCount As Integer
    Dim iColors(1 To 5, 0 To 1) As Integer
    Dim iColor As Integer
'Imposta i colori per le serie in Bianco e Nero
    iColors(1, 0) = 1 'Nero
    iColors(2, 0) = 56 'Grigio-80%
    iColors(3, 0) = 16 'Grrigio-50%
    iColors(4, 0) = 48 'Grigio-40%
    iColors(5, 0) = 15 'Grigio-25%
'Imposta i colori per le serie a Colori
    iColors(1, 1) = 55 'Indaco
    iColors(2, 1) = 7 'Rosa
    iColors(3, 1) = 6 'Giallo
    iColors(4, 1) = 8 'Turchese
    iColors(5, 1) = 13 'Violetto
'Alterna colore/bianco e nero da 0 a 1 o da 1 a 0
    bColored = 1 - bColored
    Set cht = ActiveChart
'verifica che sia selezionato un grafico
    If cht Is Nothing Then
        MsgBox ("Seleziona un grafico")
        Exit Sub
    End If
    Set chtSC = cht.SeriesCollection
    'Verifica il MIN del numero di serie o
    'colori e fa solo il minimo
    iSeriesCount = Application.WorksheetFunction.Min _
      (UBound(iColors), chtSC.Count)
    For x = 1 To iSeriesCount
        'Definisce il colore
        iColor = iColors(x, bColored)
        'Imposta il colore della LINEA
        chtSC(x).Border.ColorIndex = iColor
        'Colore del marcatore
        With chtSC(x)
            .MarkerBackgroundColorIndex = xlNone
            .MarkerForegroundColorIndex = iColor
        End With
    Next x
End Sub

 

 

Questo esempio non funzionerà con tutti i tipi di grafico (ad esempio, funziona bene con i grafici a linee, ma non con gli istogrammi); dovrai modificarlo per riflettere le tue esigenze. Servirà, tuttavia, come punto di partenza per creare la tua macro.

 

 

Tags: , , , , , , , , , , , , , , , , ,

Ti è stato utile?